      $set repository(update on checking on)
      *-----------------------------------------------------------------
       class-id. Employee as "Employee" inherits Person.

       repository.
           class Employee as "Employee"
           class Person as "Person"
           class CharString as "String"
           .

       factory.

      *---------------------------------------------
      *
      * newEmployee: Allocates a new object reference and invokes
      *   initEmployee to initialize the new instance
      *
      *---------------------------------------------

       method-id. "newEmployee".
       data division.
       linkage section.
       01  lk-PersonName pic x any length.
       01  lk-dob        pic x any length.
       01  new-object   usage object reference active-class.
       procedure division using lk-PersonName lk-dob
                          returning new-object.
           invoke super "newperson" using lk-PersonName
                                           lk-dob
                                     returning new-object
           exit method
           .
       end method "newEmployee".

       end factory.

      *-----------------------------------------------------------------

       object.
       working-storage section.
       01  jobTitle usage object reference CharString property.

       method-id. "display" override.
       procedure division.
           invoke super "display"
           display "Job title: " with no advancing
           display " " with no advancing
           invoke jobTitle "displaynl"
           exit method.
       end method "display".

       method-id. "finalize" override.
       procedure division.
           invoke super "finalize"
           invoke jobTitle "finalize"
           exit method.
       end method "finalize".

       end object.
       end class Employee.
       
