      $set repository(update on checking on)
      *-----------------------------------------------------------------
      * Helper class for the linked list class
      *-----------------------------------------------------------------
       class-id. LinkEntry as "LEntry" inherits Base.

       repository.
           class Base as "base"
           class LinkEntry as "LEntry"
           .

       factory.

       method-id. "newEntry".
       linkage section.
       01 lk-element usage object reference.
       01 new-object usage object reference LinkEntry.
       procedure division using by value lk-element
                          returning new-object.
           invoke super "new" returning new-object.
           invoke new-object "initentry" using by value lk-element
           exit method.
       end method "newEntry".

       end factory.

       object.
       working-storage section.
       01  element     usage object reference           property.
       01  nextElement usage object reference LinkEntry property.

       method-id. "initEntry".
       linkage section.
       01  lk-element usage object reference.
       procedure division using by value lk-element.
           set element to lk-element
           set nextElement to null
           exit method.
       end method "initEntry".

       end object.

       end class LinkEntry.

